Mercurial

comparison third_party/libuv/configure.ac @ 160:948de3f54cea

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
[ThirdParty] Added libuv
author June Park <parkjune1995@gmail.com>
date Wed, 14 Jan 2026 19:39:52 -0800
parents
children
comparison
equal deleted inserted replaced
159:05cf9467a1c3 160:948de3f54cea
1 # Copyright (c) 2013, Ben Noordhuis <[email protected]>
2 #
3 # Permission to use, copy, modify, and/or distribute this software for any
4 # purpose with or without fee is hereby granted, provided that the above
5 # copyright notice and this permission notice appear in all copies.
6 #
7 # THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
8 # WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
9 # MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
10 # ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
11 # WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
12 # ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
13 # OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
14
15 AC_PREREQ(2.57)
16 AC_INIT([libuv], [1.51.0], [https://github.com/libuv/libuv/issues])
17 AC_CONFIG_MACRO_DIR([m4])
18 m4_include([m4/libuv-extra-automake-flags.m4])
19 m4_include([m4/as_case.m4])
20 m4_include([m4/libuv-check-flags.m4])
21 AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects] UV_EXTRA_AUTOMAKE_FLAGS)
22 AM_MAINTAINER_MODE([enable]) # pass --disable-maintainer-mode if autotools may be unavailable
23 AC_CANONICAL_HOST
24 AC_ENABLE_SHARED
25 AC_ENABLE_STATIC
26 AC_PROG_CC
27 AM_PROG_CC_C_O
28
29 CC_ATTRIBUTE_VISIBILITY([default], [
30 CC_FLAG_VISIBILITY([CFLAGS="${CFLAGS} -fvisibility=hidden"])
31 ])
32 # Xlc has a flag "-f<filename>". Need to use CC_CHECK_FLAG_SUPPORTED_APPEND so
33 # we exclude -fno-strict-aliasing for xlc
34 CC_CHECK_FLAG_SUPPORTED_APPEND([-fno-strict-aliasing])
35 CC_CHECK_CFLAGS_APPEND([-g])
36 CC_CHECK_CFLAGS_APPEND([-std=gnu11])
37 CC_CHECK_CFLAGS_APPEND([-Wall])
38 CC_CHECK_CFLAGS_APPEND([-Wextra])
39 CC_CHECK_CFLAGS_APPEND([-Wno-long-long])
40 CC_CHECK_CFLAGS_APPEND([-Wno-unused-parameter])
41 CC_CHECK_CFLAGS_APPEND([-Wstrict-prototypes])
42 # AM_PROG_AR is not available in automake v0.11 but it's essential in v0.12.
43 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
44 # autoconf complains if AC_PROG_LIBTOOL precedes AM_PROG_AR.
45 AC_PROG_LIBTOOL
46 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
47 LT_INIT
48 AX_PTHREAD([
49 LIBS="$LIBS $PTHREAD_LIBS"
50 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
51 ])
52 AC_SEARCH_LIBS([dlopen], [dl])
53 AC_SEARCH_LIBS([kstat_lookup], [kstat])
54 AC_SEARCH_LIBS([gethostbyname], [nsl])
55 AC_SEARCH_LIBS([perfstat_cpu], [perfstat])
56 AC_SEARCH_LIBS([clock_gettime], [rt])
57 AC_SEARCH_LIBS([sendfile], [sendfile])
58 AC_SEARCH_LIBS([socket], [socket])
59 AC_SYS_LARGEFILE
60 AM_CONDITIONAL([AIX], [AS_CASE([$host_os],[aix*], [true], [false])])
61 AM_CONDITIONAL([ANDROID], [AS_CASE([$host_os],[linux-android*],[true], [false])])
62 AM_CONDITIONAL([CYGWIN], [AS_CASE([$host_os],[cygwin*], [true], [false])])
63 AM_CONDITIONAL([DARWIN], [AS_CASE([$host_os],[darwin*], [true], [false])])
64 AM_CONDITIONAL([DRAGONFLY],[AS_CASE([$host_os],[dragonfly*], [true], [false])])
65 AM_CONDITIONAL([FREEBSD], [AS_CASE([$host_os],[freebsd*], [true], [false])])
66 AM_CONDITIONAL([HAIKU], [AS_CASE([$host_os],[haiku], [true], [false])])
67 AM_CONDITIONAL([HURD], [AS_CASE([$host_os],[gnu*], [true], [false])])
68 AM_CONDITIONAL([LINUX], [AS_CASE([$host_os],[linux*], [true], [false])])
69 AM_CONDITIONAL([MSYS], [AS_CASE([$host_os],[msys*], [true], [false])])
70 AM_CONDITIONAL([NETBSD], [AS_CASE([$host_os],[netbsd*], [true], [false])])
71 AM_CONDITIONAL([OPENBSD], [AS_CASE([$host_os],[openbsd*], [true], [false])])
72 AM_CONDITIONAL([OS390], [AS_CASE([$host_os],[openedition*], [true], [false])])
73 AM_CONDITIONAL([OS400], [AS_CASE([$host_os],[os400], [true], [false])])
74 AM_CONDITIONAL([SUNOS], [AS_CASE([$host_os],[solaris*], [true], [false])])
75 AM_CONDITIONAL([WINNT], [AS_CASE([$host_os],[mingw*], [true], [false])])
76 AS_CASE([$host_os],[mingw*], [
77 LIBS="$LIBS -lws2_32 -lpsapi -liphlpapi -luserenv -luser32 -ldbghelp -lole32 -lshell32"
78 ])
79 AS_CASE([$host_os], [solaris2.10], [
80 CFLAGS="$CFLAGS -DSUNOS_NO_IFADDRS"
81 ])
82 AS_CASE([$host_os], [netbsd*], [AC_CHECK_LIB([kvm], [kvm_open])])
83 AS_CASE([$host_os], [haiku], [
84 LIBS="$LIBS -lnetwork"
85 ])
86 AC_CHECK_HEADERS([sys/ahafs_evProds.h])
87 AC_CONFIG_FILES([Makefile libuv.pc])
88 AC_CONFIG_LINKS([test/fixtures/empty_file:test/fixtures/empty_file])
89 AC_CONFIG_LINKS([test/fixtures/load_error.node:test/fixtures/load_error.node])
90 AC_CONFIG_LINKS([test/fixtures/lorem_ipsum.txt:test/fixtures/lorem_ipsum.txt])
91 AC_CONFIG_LINKS([test/fixtures/one_file/one_file:test/fixtures/one_file/one_file])
92 AC_OUTPUT